Amazon DynamoDB テーブルを別のアカウントに移行する

2022.9.2

Topics

はじめに
概要
やってみる
まとめ
参考記事

はじめに

DynamoDB テーブルを別の AWS アカウントに移行するには DynamoDB のエクスポート・インポート機能を使えば簡単に実現できます。

2022/08 のアップデートで DynamoDB にインポート機能が追加されたため、ほぼ DynamoDB だけでアカウント移行ができるようになりました。
Amazon DynamoDB が Amazon S3 のデータを新しいテーブルにインポートできるようになりました | Amazon Web Services ブログ

概要

DynamoDB テーブルを別の AWS アカウントに移行するには、次の手順を実行します。

DynamoDB テーブルデータを別のアカウントの S3 バケットにエクスポートします。
DynamoDB インポート機能を使用して S3 からデータをインポートします。

DynamoDBアカウント移行構成図

やってみる

リソースの作成は Terraform を使用して実施します。
その後の作業である「エクスポート・インポート」はコンソール画面で操作します。

provider.tf と variables.tf は省略します。

必要リソース作成

アカウント A の移行元に DynamoDB テーブルを作成します
アカウント B にエクスポートするデータを格納する S3 を作成します

アカウント A に DynamoDB 作成

大事なポイントとして、DynamoDB のエクスポート機能はPITRが有効じゃないと使用できません。

新機能 – Amazon DynamoDB に継続的バックアップと Point-In-Time-Recovery(PITR)機能が追加されました | Amazon Web Services ブログ

resource "aws_dynamodb_table" "STANDARD" {
  name           = "GameScores"
  billing_mode   = "PROVISIONED"
  read_capacity  = 20
  write_capacity = 20
  hash_key       = "UserId"
  range_key      = "GameTitle"
  point_in_time_recovery {
    enabled = true
  }
  attribute {
    name = "UserId"
    type = "S"
  }

  attribute {
    name = "GameTitle"
    type = "S"
  }
}

Terraform でテーブルと合わせて、検証用に 2 件のデータを作成します。

resource "aws_dynamodb_table_item" "example1" {
  table_name = aws_dynamodb_table.STANDARD.name
  hash_key   = aws_dynamodb_table.STANDARD.hash_key
  range_key  = aws_dynamodb_table.STANDARD.range_key
  item       = <<ITEM
{
  "UserId": {"S": "test"},
  "GameTitle": {"S": "4"}
}
ITEM
}
resource "aws_dynamodb_table_item" "example2" {
  table_name = aws_dynamodb_table.STANDARD.name
  hash_key   = aws_dynamodb_table.STANDARD.hash_key
  range_key  = aws_dynamodb_table.STANDARD.range_key
  item       = <<ITEM
{
  "UserId": {"S": "test"},
  "GameTitle": {"S": "5"}
}
ITEM
}

テーブルとデータが出来たことを確認します。

DynamoDBテーブル概要

移行元テーブルの2件のデータ

アカウント B に S3 作成

次に DynamoDB のエクスポート先に指定する S3 を作成します。

アカウント A の DynamoDB がアクセスできるように、S3 バケットポリシーで権限を設定します。
var.account_idはアカウント A の AWS アカウント ID を入力してください。

ポリシーは以下を参考にしました。
DynamoDB でテーブルのエクスポートをリクエストする – Amazon DynamoDB

resource "aws_s3_bucket" "bucket" {
  bucket = "${var.project_name}-bucket"
}
resource "aws_s3_bucket_acl" "bucket_acl" {
  bucket = aws_s3_bucket.bucket.id
  acl    = "private"
}
resource "aws_s3_bucket_policy" "allow_access_from_another_account" {
  bucket = aws_s3_bucket.bucket.id
  policy = data.aws_iam_policy_document.allow_access_from_another_account.json
}

data "aws_iam_policy_document" "allow_access_from_another_account" {
  statement {
    principals {
      type        = "AWS"
      identifiers = ["${var.account_id}"]
    }
    effect = "Allow"
    actions = [
      "s3:AbortMultipartUpload",
      "s3:PutObject",
      "s3:PutObjectAcl",
      "s3:ListBucket"
    ]

    resources = [
      "${aws_s3_bucket.bucket.arn}",
      "${aws_s3_bucket.bucket.arn}/*",
    ]
  }
}

バケットが出来たことを確認します。

作成したS3バケット