基本的にlocals内の変数のみ変更すればapplyが通るかと思います。

locals {
  aws_id      = XXXXXXXXXXXX
  name_prefix = "Techblog"
  region      = "ap-northeast-1"
  acm_arn     = "arn:aws:acm:ap-northeast-1:XXXXXXXXXXXX:certificate/xxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx"
}

provider "aws" {
  region = local.region
}

# EC2インスタンスの作成
module "ec2" {
  source  = "terraform-aws-modules/ec2-instance/aws"
  version = "5.5.0"

  name                        = "${local.name_prefix}-ec2"
  ami                         = "ami-012261b9035f8f938"  # Amazon Linux 2023
  instance_type               = "m6a.xlarge"
  availability_zone           = element(module.vpc.azs, 0)
  subnet_id                   = element(module.vpc.public_subnets, 0)
  iam_instance_profile        = module.nitro_role.iam_instance_profile_id
  vpc_security_group_ids      = [aws_security_group.sg_web.id]
  associate_public_ip_address = true
  cpu_credits                 = "standard"
  disable_api_termination     = false
  enclave_options_enabled     = true

  root_block_device = [
    {
      encrypted   = true
      volume_type = "gp3"
      volume_size = 10
      throughput  = 125
    }
  ]

  user_data          = file("install.sh")
  ignore_ami_changes = false

}

# VPCの作成
module "vpc" {
  source  = "terraform-aws-modules/vpc/aws"
  version = "5.2.0"

  name = "${local.name_prefix}-vpc"
  cidr = "10.0.0.0/16"

  azs            = ["${local.region}a", "${local.region}c"]
  public_subnets = ["10.0.0.0/24", "10.0.1.0/24"]
}

# EC2,ACMと紐付けるIAMロールの作成
module "nitro_role" {
  source  = "terraform-aws-modules/iam/aws//modules/iam-assumable-role"
  version = "5.32.0"

  create_role             = true
  create_instance_profile = true
  role_requires_mfa       = false

  trusted_role_services = ["ec2.amazonaws.com"]
  role_name             = "${local.name_prefix}NitroEnclavesRole"

  custom_role_policy_arns = [
    "arn:aws:iam::aws:policy/AmazonSSMManagedInstanceCore",
    aws_iam_policy.nitro_enclaves_policy.arn
  ]
}

resource "aws_iam_policy" "nitro_enclaves_policy" {
  name   = "${local.name_prefix}NitroEnclavesPolicy"
  policy = data.aws_iam_policy_document.nitro_enclaves_policy_document.json
}

data "aws_iam_policy_document" "nitro_enclaves_policy_document" {
  statement {
    sid    = "NitroEnclaves"
    effect = "Allow"
    actions = [
      "ec2:AssociateEnclaveCertificateIamRole",
      "ec2:GetAssociatedEnclaveCertificateIamRoles",
      "ec2:DisassociateEnclaveCertificateIamRole"
    ]

    resources = [
      "arn:aws:acm:${local.region}:${local.aws_id}:certificate/*",
      "arn:aws:iam::${local.aws_id}:role/*"
    ]
  }
}

# ステップ4でのACMとIAMロールの紐づけ
resource "awscc_ec2_enclave_certificate_iam_role_association" "acm_enclave_certificate" {
  certificate_arn = local.acm_arn
  role_arn        = module.nitro_role.iam_role_arn
}

# ステップ5のACMとIAMの紐付け時に必要なロールのアタッチ
resource "aws_iam_role_policy_attachment" "nitro_enclaves_kms_policy_attach" {
  role       = module.nitro_role.iam_role_name
  policy_arn = aws_iam_policy.nitro_enclaves_kms_policy.arn
}

resource "aws_iam_policy" "nitro_enclaves_kms_policy" {
  name   = "${local.name_prefix}NitroEnclavesKMSPolicy"
  policy = data.aws_iam_policy_document.nitro_enclaves_kms_policy_document.json
}

data "aws_iam_policy_document" "nitro_enclaves_kms_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "s3:GetObject"
    ]

    resources = [
      "arn:aws:s3:::${awscc_ec2_enclave_certificate_iam_role_association.acm_enclave_certificate.certificate_s3_bucket_name}/*"
    ]
  }

  statement {
    sid    = "VisualEditor0"
    effect = "Allow"
    actions = [
      "kms:Decrypt"
    ]

    resources = ["arn:aws:kms:${local.region}:*:key/${awscc_ec2_enclave_certificate_iam_role_association.acm_enclave_certificate.encryption_kms_key_id}"]
  }

  statement {
    effect = "Allow"
    actions = [
      "iam:GetRole"
    ]

    resources = ["arn:aws:iam::${local.aws_id}:role/${module.nitro_role.iam_role_name}"]
  }
}

resource "aws_security_group" "sg_web" {
  name   = "${local.name_prefix}-sg-web"
  vpc_id = module.vpc.vpc_id

  ingress {
    from_port   = 443
    to_port     = 443
    protocol    = "tcp"
    cidr_blocks = ["0.0.0.0/0"]
  }

  ingress {
    from_port   = 80
    to_port     = 80
    protocol    = "tcp"
    cidr_blocks = ["0.0.0.0/0"]
  }

  egress {
    from_port        = 0
    to_port          = 0
    protocol         = "-1"
    cidr_blocks      = ["0.0.0.0/0"]
    ipv6_cidr_blocks = ["::/0"]
  }
}

#!/bin/bash
yum update -y

## Apache Setup
yum -y install httpd mod_ssl
systemctl enable httpd
systemctl start httpd

# nitro-acm Setup
yum install aws-nitro-enclaves-acm -y